import flash.events.Event;

import mx.core.UIComponent;
import mx.events.ListEvent;


/**
 * Called by all event handlers to record the action taken that caused
 * the event.  Calls a javascript function which in turn records the event.
 */
private function jsRecordFlexAction(id:String, functionName:String, 
                                    param1:String, param2:String):void {     
  var info:Object = new Object();
  info.id = id;
  info.functionName = functionName;
  info.param1 = param1;
  info.param2 = param2;

  if (ExternalInterface.available)
  {
    ExternalInterface.call("recordFlexAction", info);    
  }
}

/**
 * Register all the functions available from javascript
 * @return  true if the functions were properly registered, false otherwise
 */
private function registerTestCallbacks():Boolean {
	var retval:Boolean = false;
	if(ExternalInterface.available==true) {
	    ExternalInterface.addCallback("selectByLabel", selectByLabel);
	    ExternalInterface.addCallback("clickButton", clickButton);
   	  ExternalInterface.addCallback("setInputText", setInputText);
	    ExternalInterface.addCallback("getLabelText", getLabelText);
	    retval = true;
	}
	return retval;
}

/**
 * Find a UIComponent using its id attribute, wherever it is in the application
 * @param  id  id attribute of the UIComponent to return
 * @return     the UIComponent corresponding to the id, or null if not found
 */
private function getElementById(id:String):UIComponent {
	return getElementByIdRecursive(id, this);
}

private function getElementByIdRecursive(id:String, root:UIComponent):UIComponent {
	for(var i:int = 0; i<root.numChildren; i++) {
		try {
			var child:UIComponent = UIComponent(root.getChildAt(i));
			if(child.id == id) return child;
			var node:UIComponent = getElementByIdRecursive(id, child);
			if(node!=null) return node;
		}
		catch(e:Error) {
		}
	}
	return null;
}

/**
 * Select a value in a combo box
 * @param  id     id attribute of the combo box to use
 * @param  label  label to select in the combo box
 * @return        true if there was no exception, false otherwise
 */
private function selectByLabel(id:String, label:String):Boolean {	
	var combo:ComboBox, retval:Boolean = false;
	try {
		combo = ComboBox(getElementById(id));
		combo.selectedItem = label;
		combo.dispatchEvent(new ListEvent(ListEvent.CHANGE));
		retval = true;
	}
	catch(e:Error) {
	}
	return retval;
}

/**
 * Click a button
 * @param  id  id attribute of the button to click
 * @return     true if there was no exception, false otherwise
 */
public function clickButton(id:String):Boolean {
	var btn:Button, retval:Boolean = false;
	try {
		btn = Button(getElementById(id));
		btn.dispatchEvent(new MouseEvent(MouseEvent.CLICK));
		retval = true;
	}
	catch(e:Error) {
	}
	return retval;
}

/**
 * Set a text input value
 * @param  id    id attribute of the text input to set the text of
 * @param  text  the text to set
 * @return       true if there was no exception, false otherwise
 */
private function setInputText(id:String, text:String):Boolean {
	var input:TextInput, retval:Boolean = false;	
	try {
		input = TextInput(getElementById(id));
		input.text = text;
		input.dispatchEvent(new Event(flash.events.Event.CHANGE));
		retval = true;
	}
	catch(e:Error) {
	}
	return retval;
}

/**
 * Get the text of the "TestFlexLabel" label
 * @return     the value of the label text attribute, or null if an exception occured
 */
private function getLabelText():String {
	var label:Label, retval:String = null, id:String="TestFlexLabel";	
	try {
		label = Label(getElementById(id));
		retval = label.text;
	}
	catch(e:Error) {
	}
	return retval;
}